SQL Server関連

ASPのActiveX dllを使った連動プルダウンの実装

たにぐち — Thu, 21 Jul 2005 02:37:00 GMT

http://blogs.sqlpassj.org/masatotaniguchi/archive/2005/07/09/12119.aspx

の続きになります。
前回は、aspファイルからデータアクセスを分離してみましたが、そのデータアクセスオブジェクト(DAO)はaspから呼ばれるとは限りません。別のActiveX dllから呼ばれ、例えばWEBの画面を動的に構成するということも考えられます。その例として取り上げたのが連動（連結）プルダウン（コンボボックス）です。部署を選択すると、その部署に属する社員だけが選択されるといったVisual Basic 6.0やVBAのプログラミングではおなじみのインターフェースです。WEBアプリケーションでは連動プルダウンがいくつもある場合、部署を選択するたびにリクエストを行うと、ユーザーにもサーバーにも負担をかけてしまいます。
そこで、例えばこのようなActiveX dllを作ってみました。

ソースファイル：linkedlist.asp
<HTML>
<HEAD>
<TITLE>連動プルダウン</TITLE>
<%
Set EmpLinkedListBox = Server.CreateObject("ScottView.clsEmpLinkedListBox")
EmpLinkedListBox.InitFunctionName = "onInit"
EmpLinkedListBox.ParentOnChangeFunctionName = "parentOnChange"
EmpLinkedListBox.ParentListName = "parentList"
EmpLinkedListBox.ChildListName = "childList"
%>
<%=empLinkedListBox.GetJavaScript%>
</HEAD>
<BODY onLoad="onInit(document.linkedList.parentList, document.linkedList.childList)">
<FORM name="linkedList">
   部署 <SELECT name="parentList" onChange="parentOnChange(document.linkedList.parentList, document.linkedList.childList)">
   </SELECT><BR>
   社員 <SELECT name="childList">
   </SELECT>
</FORM>
</BODY>
</HTML>

上のようなaspが変換後、下のようになれば成功です。

<HTML>
<HEAD>
<TITLE>連動プルダウン</TITLE>
<SCRIPT LANGUAGE="JavaScript1.1">
<!--
function onInit(parentList, childList) {
      childList.options[0] = new Option("CLARK", "7782")
      childList.options[1] = new Option("KING", "7839")
      childList.options[2] = new Option("MILLER", "7934")
      parentList.options[0] = new Option("ACCOUNTING", "10")
      parentList.options[1] = new Option("RESEARCH", "20")
      parentList.options[2] = new Option("SALES", "30")
      parentList.options[3] = new Option("OPERATIONS", "40")

}
function parentOnChange(parentList, childList) {
   var parentListValue = parentList.value;
   childList.length = 0;
   if (parentListValue == "10") {
      childList.options[0] = new Option("CLARK", "7782")
      childList.options[1] = new Option("KING", "7839")
      childList.options[2] = new Option("MILLER", "7934")
   } else if (parentListValue == "20") {
      childList.options[0] = new Option("SMITH", "7369")
      childList.options[1] = new Option("JONES", "7566")
      childList.options[2] = new Option("SCOTT", "7788")
      childList.options[3] = new Option("ADAMS", "7876")
      childList.options[4] = new Option("FORD", "7902")
   } else if (parentListValue == "30") {
      childList.options[0] = new Option("ALLEN", "7499")
      childList.options[1] = new Option("WARD", "7521")
      childList.options[2] = new Option("MARTIN", "7654")
      childList.options[3] = new Option("BLAKE", "7698")
      childList.options[4] = new Option("TURNER", "7844")
      childList.options[5] = new Option("JAMES", "7900")
   } else if (parentListValue == "40") {
   }
}
// -->
</SCRIPT>

</HEAD>
<BODY onLoad="onInit(document.linkedList.parentList, document.linkedList.childList)">
<FORM name="linkedList">
   部署 <SELECT name="parentList" onChange="parentOnChange(document.linkedList.parentList, document.linkedList.childList)">
   </SELECT><BR>
   社員 <SELECT name="childList">
   </SELECT>
</FORM>
</BODY>
</HTML>

この例では、連動プルダウンは一つですが、SELECTタグの名前と、それにあわせて関数を呼ぶ時の引数を変えれば部署-社員の連動プルダウンはいくつも作ることができます（ただし初期化関数は個数分繰り返して呼ぶ必要があります）。変換後のHTMLソースをじっと眺めると、onInit関数は親子の初期化、parentOnChange関数はif分の条件式と、その{}の中に特徴があります。そこで、初期化関数(onInit)のオプション生成をコレクションにしたものと、親プルダウン変更時関数(parentOnChange)のIFブロック（部署ごとにグループ化された社員のオプション生成）をコレクションにしたものを渡せば、上記JavaScriptを生成するクラスを作成してみました。ScottViewという名前のActiveX dllプロジェクトをつくり、プロジェクトメニューの参照設定で、ScottDAOを追加します。そして以下のソースファイルを追加します。JavaScript用標準モジュール以外全てクラスモジュールですがclsEmpLinkedListBox以外はInstancingプロパティをPrivateにします。エラー処理、データのチェックは省略してあります。

' ソースファイル clsLinkedListBoxBuilder：クラスモジュール
Private m_ParentListName As String
Private m_ChildListName As String
Private m_InitFunctionName As String
Private m_ParentOnChangeFunctionName As String
Private m_InitFunctionOptions As Collection
Private m_ParentOnChangeIfBlocks As Collection

' 初期化関数名
Public Property Let InitFunctionName(strInitFunctionName As String)
m_InitFunctionName = strInitFunctionName
End Property

' 親リスト変更イベント関数名
Public Property Let ParentOnChangeFunctionName( _
strParentOnChangeFunctionName As String)
m_ParentOnChangeFunctionName = strParentOnChangeFunctionName
End Property

' 親リスト名
Public Property Let ParentListName(strParentListName As String)
m_ParentListName = strParentListName
End Property

Public Property Get ParentListName() As String
ParentListName = m_ParentListName
End Property

' 子リスト名
Public Property Let ChildListName(strChildListName As String)
m_ChildListName = strChildListName
End Property

Public Property Get ChildListName() As String
ChildListName = m_ChildListName
End Property

' 初期化関数本体
Public Property Set InitFunctionOptions(Options As Collection)
Set m_InitFunctionOptions = Options
End Property

' ParentOnChange関数用If Block
Public Property Set ParentOnChangeIfBlocks(IfBlocks As Collection)
Set m_ParentOnChangeIfBlocks = IfBlocks
End Property

' 初期化関数作成
Private Function CreateInitFunctionBody() As String
    Dim strRet As String
    Dim strOption As Variant

    strRet = ""

    For Each strOption In m_InitFunctionOptions
        strRet = strRet & JS_INDENT & strOption & vbCrLf
    Next

    CreateInitFunctionBody = strRet

End Function

' ParentOnChange関数作成
Private Function CreateParentOnChangeFunctionBody() As String

    Dim strRet As String
    Dim IfBlock As clsParentOnChangeIfBlock

    Const FIRST_IF_TEMPLATE = JS_INDENT & "if (parentListValue == ""?"") {"
    Const ELSE_IF_TEMPLATE = JS_INDENT & "} else if (parentListValue == ""?"") {"
    Const CLOSE_IF = JS_INDENT & "}"

    ' 選択されている親リストのキーをparentListValue変数に代入するjavaScriptコード
    strRet = JS_INDENT & "var parentListValue = " & m_ParentListName & ".value;" & vbCrLf
    ' 子リストの内容をクリア(length = 0)
    strRet = strRet & JS_INDENT & m_ChildListName & ".length = 0;" & vbCrLf

    ' IFブロックの作成
    Dim blnFirstBlock As Boolean
    blnFirstBlock = True
    For Each IfBlock In m_ParentOnChangeIfBlocks
        If blnFirstBlock Then
            strRet = strRet & Replace(FIRST_IF_TEMPLATE, "?", IfBlock.Key) & vbCrLf
            strRet = strRet & IfBlock.Body
        Else
            strRet = strRet & Replace(ELSE_IF_TEMPLATE, "?", IfBlock.Key) & vbCrLf
            strRet = strRet & IfBlock.Body
        End If
        blnFirstBlock = False
    Next
    ' IFブロックを閉じる
    strRet = strRet & CLOSE_IF

    CreateParentOnChangeFunctionBody = strRet

End Function

' JavaScript作成
Public Function GetJavaScript() As String

    Dim strRet As String

    ' 初期化関数引数
    Dim strInitVar As String
    ' ParentOnChange関数引数
    Dim strParentOnChangeVar As String
    strInitVar = m_ParentListName & ", " & m_ChildListName
    strParentOnChangeVar = m_ParentListName & ", " & m_ChildListName

    ' JSタグ
    strRet = JS_START_TAG
    ' 初期化関数
    strRet = strRet & CretateJSFunction(m_InitFunctionName, _
            strInitVar, CreateInitFunctionBody()) & vbCrLf
    ' ParentOnChange関数
    strRet = strRet & CretateJSFunction(m_ParentOnChangeFunctionName, _
            strParentOnChangeVar, CreateParentOnChangeFunctionBody()) & vbCrLf

    strRet = strRet & JS_END_TAG

    GetJavaScript = strRet

End Function

ただし、親プルダウン変更時関数(parentOnChange)のIFブロックを保存するために以下のクラスを用いました。

' ソースファイル clsParentOnChangeIfBlock：クラスモジュール
Private m_Key As String

Private m_Body As String

Public Property Let Key(strKey As String)
m_Key = strKey
End Property

Public Property Get Key() As String
Key = m_Key
End Property

Public Property Let Body(strBody As String)
m_Body = strBody
End Property

Public Property Get Body() As String
Body = m_Body
End Property

またJavaScript用の共通関数として、以下の標準モジュールを使用しています。Active X dllではグローバル変数の使用はご法度なので注意が必要です。

' ソースファイル JavaScript：標準モジュール
' JavaScriptタグ
Public Const JS_START_TAG = " " & vbCrLf

' インデント
Public Const JS_INDENT = " "

' JavaScript関数を作成
Public Function CretateJSFunction(strFunctionName As String, _
        strVar As String, strFunctionBody As String) As String

    CretateJSFunction = "function " & _
        strFunctionName & "(" & strVar & ") {" & _
        vbCrLf & strFunctionBody & vbCrLf & "}"

End Function

' オプションを作成
Public Function CreateJSOption( _
        strSelectName As String, intOptionIndex As Integer, _
        strText As String, strValue As String)
    CreateJSOption = strSelectName & ".options" & "[" & intOptionIndex & "]"
    CreateJSOption = CreateJSOption & _
        " = new Option(""" & strText & """, """ & strValue & """)"
End Function

clsLinkedListBoxBuilderを包み込むような感じで、clsEmpLinkedListBoxクラスを作成します。
ScottDAOで作成したclsEmpDaoのほかに、部署用のclsDeptDaoが追加されています。
clsDeptDaoの作り方はclsEmpDaoと全く同じです。

' ソースファイル clsEmpLinkedListBox：クラスモジュール

Private LinkedListBoxBuilder As clsLinkedListBoxBuilder

' 初期化関数名
Public Property Let InitFunctionName(strInitFunctionName As String)
LinkedListBoxBuilder.InitFunctionName = strInitFunctionName
End Property

' 親リスト変更イベント関数名
Public Property Let ParentOnChangeFunctionName( _
        strParentOnChangeFunctionName As String)
    LinkedListBoxBuilder.ParentOnChangeFunctionName = _
            strParentOnChangeFunctionName
End Property

' 親リスト名
Public Property Let ParentListName(strParentListName As String)
LinkedListBoxBuilder.ParentListName = strParentListName
End Property

' 子リスト名
Public Property Let ChildListName(strChildListName As String)
LinkedListBoxBuilder.ChildListName = strChildListName
End Property

' clsLinkedListBoxBuilderクラス初期化
Private Sub Class_Initialize()
Set LinkedListBoxBuilder = New clsLinkedListBoxBuilder
End Sub

Public Function GetJavaScript() As String

    Dim ScottDaoFactory As clsScottDAOFactory
    Dim EmpDao As clsEmpDao
    Dim DeptDao As clsDeptDao
    Dim Dept As Collection
    Dim DeptVo As clsDeptVo

    ' LinkedListBoxBuilderに渡す
    ' InitFunctionOptionsプロパティと
    ' ParentOnChangeIfBlocksプロパティ
    Dim InitFunctionOptions As Collection
    Dim ParentOnChangeIfBlocks As Collection
    Set InitFunctionOptions = New Collection
    Set ParentOnChangeIfBlocks = New Collection

    ' 部署リストボックスの配列のINDEX用
    Dim intDeptCount As Integer

    ' 初期化関数オプション一時保存用
    Dim InitFunctionOption As String

    ' DAOFactoryインスタンス作成
    Set ScottDaoFactory = New clsScottDAOFactory

    ' 部署、社員DAO取得
    Set DeptDao = ScottDaoFactory.DeptDao
    Set EmpDao = ScottDaoFactory.EmpDao

    ' 部署を全て選択
    Set Dept = DeptDao.SelectDept

    ' 全選択された部署ごとのループ
    intDeptCount = 0
    For Each DeptVo In Dept

        Dim Emp As Collection
        Dim EmpVo As clsEmpVo

        ' 部署（親）リスト変更イベント関数IFブロック作成
        Dim ParentOnChangeIfBlock As clsParentOnChangeIfBlock
        Set ParentOnChangeIfBlock = New clsParentOnChangeIfBlock
        ParentOnChangeIfBlock.Key = DeptVo.DeptNo
        ParentOnChangeIfBlock.Body = ""

        intDeptCount = intDeptCount + 1

        Set Emp = EmpDao.SelectEmp(DeptVo.DeptNo)

        ' 社員番号リストボックスの配列のINDEX用
        Dim intEmpCount As Integer
        intEmpCount = 0
        ' 部署に属する社員のループ
        For Each EmpVo In Emp

            intEmpCount = intEmpCount + 1
            If intDeptCount = 1 Then
                ' 初期化関数は、社員（子）リストボックスに
                ' 最初のINDEXの部署の社員をリストする
                InitFunctionOption = JS_INDENT & _
                    CreateJSOption(LinkedListBoxBuilder.ChildListName, _
                    intEmpCount - 1, EmpVo.Ename, EmpVo.EmpNo)
                Call InitFunctionOptions.Add(InitFunctionOption)
            End If
            ' ParentOnChangeのIfブロック内のオプション(INDENT二つ)
            ParentOnChangeIfBlock.Body = ParentOnChangeIfBlock.Body & _
                JS_INDENT & JS_INDENT & _
                CreateJSOption(LinkedListBoxBuilder.ChildListName, _
                    intEmpCount - 1, EmpVo.Ename, EmpVo.EmpNo) & vbCrLf
        Next
        ' 初期化関数の本体を作成
        InitFunctionOption = JS_INDENT & _
            CreateJSOption(LinkedListBoxBuilder.ParentListName, intDeptCount - 1, _
            DeptVo.DName, DeptVo.DeptNo)
        Call InitFunctionOptions.Add(InitFunctionOption)
        ' その部署の社員分のオプションをBodyにつめ終えたので、
        ' ParentOnChangeIfBlocksコレクションに追加
        Call ParentOnChangeIfBlocks.Add(ParentOnChangeIfBlock)
    Next

    ScottDaoFactory.CloseConnection

    Set LinkedListBoxBuilder.InitFunctionOptions = InitFunctionOptions
    Set LinkedListBoxBuilder.ParentOnChangeIfBlocks = ParentOnChangeIfBlocks

    GetJavaScript = LinkedListBoxBuilder.GetJavaScript

End Function

もし、他の連動プルダウンがほしくなった時は、同じようにclsLinkedListBoxBuilderを使い新たにクラスを作成します。

ASP(非ASP.NET)で、なるべくコードの変更を少なくして複数のデータベースに確実に対応できるようにする

たにぐち — Sat, 09 Jul 2005 02:43:00 GMT

http://blogs.sqlpassj.org/masatotaniguchi/archive/2005/06/10/9475.aspx
のASP版(非ASP.NET)です。ActiveX dllを使用し、ASPファイルからデータアクセス部分を分離、少ない変更で複数のデータベースに対応できるようにします。

Visual Basic 6.0で、ActiveX dllを作成し、ScottDAOという名前をつけます。これは、以前にご紹介したVB6版をActiveX dll化したものです。
※以下のソースコードはエラー処理などが省略してあり、完全ではありません。

テーブル(OracleのScott.Empテーブルと、それをSQL Server 2000にインポートしたテーブル)のレコードを保存するために、VO(Value Object)を用意します。これはVB6版と全く同じでそのまま移植できます。
Instancingプロパティは5-MultiUseとします。

' ソースコード(clsEmpVo)：クラスモジュール

' Private 変数
' 従業員番号
Private m_lngEmpNo As Long
' 従業員名
Private m_strEname As String

' 以下略

' プロパティ

Public Property Get EMPNO() As Long
EMPNO = m_lngEmpNo
End Property

Public Property Let EMPNO(lngEmpNo As Long)
m_lngEmpNo = lngEmpNo
End Property

Public Property Get Ename() As String
Ename = m_strEname
End Property

Public Property Let Ename(strEname As String)
m_strEname = strEname
End Property

' 以下略（フィールド分同じものを作ります）

インターフェースクラスは外部に公開したいため、Instancingプロパティを5-MultiUseとします。
これをこのまま公開しても、中は空っぽです。後でちょっと細工をします。

' ソースコード(clsEmpDao) ：クラスモジュール

Public Function SelectEmp(lngDeptNo As Long) As Collection

End Function

Public Function InsertEmp(EmpVo As clsEmpVo) As Boolean

End Function

Public Function UpdateEmp(EmpVo As clsEmpVo) As Boolean

End Function

Public Property Set Connection(con As Object)

End Property

clsEmpSQLServerDaoはVB6版とほとんど同じです（選択条件が部署番号になっている部分だけが違います）。このクラスは外部に公開しないため、Instancingプロパティを1-Privateとします。
Oracleについても全く同じなので、ここでは省略します。VB6版をご参照ください。
なお、nvl関数は標準モジュールにある独自の関数で動作はORACLEのNVLと全く同じです。

' ソースコード(clsEmpSQLServerDao)：クラスモジュール

Implements clsEmpDao

Private Connection As Object

Public Property Set clsEmpDao_Connection(con As Object)
Set Connection = con
End Property

Public Function clsEmpDao_SelectEmp(lngDeptNo As Long) As Collection

    Dim cmd As New ADODB.Command
    Dim result As New Collection
    Dim rs As ADODB.Recordset

    ' Commandの設定
    With cmd
        .ActiveConnection = Connection
        .CommandText = "SELECT * FROM EMP WHERE DEPTNO = ?"
        .CreateParameter , adInteger, adParamInput
        .Parameters(0).Value = lngDeptNo
    End With

    ' SQLを実行して結果セットを取得します
    Set rs = cmd.Execute

    ' Recordsetから、VOへ値を詰めます
    Do Until rs.EOF
        Dim EmpVo As clsEmpVo
        Set EmpVo = New clsEmpVo
        EmpVo.EmpNo = nvl(rs.Fields("EMPNO"), 0)
        EmpVo.Ename = nvl(rs.Fields("ENAME"), "")
        EmpVo.Job = nvl(rs.Fields("JOB"), "")
        EmpVo.Mgr = nvl(rs.Fields("MGR"), 0)
        EmpVo.HireDate = nvl(rs.Fields("HireDate"), 0)
        EmpVo.Sal = nvl(rs.Fields("SAL"), 0)
        EmpVo.Comm = nvl(rs.Fields("COMM"), 0)
        EmpVo.DeptNo = nvl(rs.Fields("DEPTNO"), 0)
        Call result.Add(EmpVo)
        rs.MoveNext
    Loop

    ' 後始末
    rs.Close
    Set rs = Nothing
    ' 戻り値(VOのコレクション)の設定
    Set clsEmpDao_SelectEmp = result
End Function

Public Function clsEmpDao_InsertEmp(EmpVo As clsEmpVo) As Boolean
' 省略
End Function

Public Function clsEmpDao_UpdateEmp(EmpVo As clsEmpVo) As Boolean
' 省略
End Function

さて、公開したいのはEmpDaoですがASPに渡したいのは中身の詰まったクラスです。
そこで以下のようなクラスを作成し外部に公開します（Instancingプロパティを5-MultiUse）。
データベースを変更する必要が出た時はここを変更します。

' ソースコード(clsScottDaoFactory)：クラスモジュール

' このクラスが生成するDAOは、clsScottDaoFactory
' のインスタンスが存命中の場合のみ使用できます。
' clsScottDaoFactoryインスタンスの消滅とともにDB
' 接続も自動的にCloseされるためです。

Private Connection As clsConnection

Public Function EmpDAO() As clsEmpDao
   Dim emp As clsEmpDao
   ' DB変更時、コードの変更が必要な場所
   Set emp = New clsEmpSQLServerDao
   ' Set emp = New clsEmpOracleDao
   Set Emp.Connection = Connection.GetConnection
   Set EmpDAO = emp
End Function

Private Sub Class_Initialize()
   Dim ConnectionFactory As New clsConnectionFactory
   Set Connection = ConnectionFactory.GetClsConnection
End Sub

' このメソッドは使用後、なるべく早く実行するようにします。
Public Sub CloseConnection()
    Connection.CloseConnection
    Set Connection = Nothing
End Sub

' 安全策
Private Sub Class_Terminate()
    If Not Connection Is Nothing Then
        Connection.CloseConnection
    End If
End Sub

ＤＢの接続のためのクラス、clsConnectionを定義します。これはインターフェースとして扱います（Instancingプロパティを5-MultiUse）。

' ソースコード(clsConnection)：クラスモジュール

Public Function GetConnection() As Object

End Function

Public Sub CloseConnection()

End Sub

SQLServerのためのclsConnectionの実装クラスを定義します（Instancingプロパティを1-Private）。Oracle用のclsOracleConnectionは省略します。

' ソースコード(clsSQLServerConnection)：クラスモジュール

Implements clsConnection

Private adoSQLServerCon As ADODB.Connection

Public Function clsConnection_GetConnection() As Object
    Set clsConnection_GetConnection = adoSQLServerCon
End Function

Public Sub clsConnection_CloseConnection()
    adoSQLServerCon.Close
    Set adoSQLServerCon = Nothing
End Sub

Private Sub Class_Initialize()
   Set adoSQLServerCon = New ADODB.Connection
    adoSQLServerCon.ConnectionString = _
        "PROVIDER=SQLOLEDB;SERVER=ServerName;DATABASE=Scott;UID=sa;PWD=*******"
    adoSQLServerCon.Open
End Sub

clsConnectionクラスを作成するためのクラスを定義します（Instancingプロパティを5-MultiUse）。

' ソースコード(clsConnectionFactory)：クラスモジュール

Public Function GetClsConnection() As clsConnection
   ' DB変更時、コードの変更が必要な場所
   Set GetClsConnection = New clsSQLServerConnection
   ' Set GetClsConnection = New clsOracleConnection
End Function

以上のActiveX dllを作成しレジストリに登録します。これをテストするためのＡＳＰファイルを用意しました。
For Eachが不安な方は、レコード数をresult.countで取得できるのでFor...Next文で書き換えてもいいと思います。

' ソースコード(ScottEmp.asp)：aspファイル

<HTML>
<BODY>
<%
Set scottDAOFactory = Server.CreateObject("ScottDAO.clsScottDAOFactory")
Set empDAO = scottDAOFactory.EmpDAO
Set result = empDAO.SelectEmp(20)
scottDAOFactory.CloseConnection
%>
<TABLE border="1">
<TR>
   <TH>従業員番号</TH>
   <TH>名前</TH>
   <TH>職種</TH>
   <TH>上司</TH>
   <TH>入社日</TH>
   <TH>給料</TH>
   <TH>歩合</TH>
   <TH>部署番号</TH>
</TR>
<%
For Each empVo In result
%>
<TR>
   <TD><%=empVo.EmpNo%></TD>
   <TD><%=empVo.Ename%></TD>
   <TD><%=empVo.Job%></TD>
   <TD><%=EmpVo.Mgr%></TD>
   <TD><%=EmpVo.Hiredate%></TD>
   <TD><%=empVo.Sal%></TD>
   <TD><%=EmpVo.Comm%></TD>
   <TD><%=empVo.deptNo%></TD>
</TR>
<%
Next
%>
</TABLE>
</BODY>
</HTML>

基本方針は、

aspファイルには画面表示ロジック以外はなるべく書かないようにする

ということです。ビジネスロジックもActiveX dllでカプセル化し、aspファイルからはそれを呼ぶだけにするようにします。

SQL Server 2000 JDBCのDBCPを使用したコネクションプーリング

たにぐち — Sat, 02 Jul 2005 15:29:00 GMT

SQL Server 2000 Driver for JDBCのConnection Poolingについては、
http://support.microsoft.com/default.aspx?scid=kb;ja;313173
に実装方法のサンプルがありますが、これはあくまでサンプルであり、完全ではないようです。腕に自信のある方はいざ実装というところなのでしょうが、そんな自信も時間の余裕もない方はやはりJakarta CommonsのDBCPの利用でしょうか。これを使うととても簡単にコネクションプーリングを使用することができます。そこで、
http://www.jajakarta.org/commons/dbcp-1.0/ja/withoutPrimary/overview-summary.htmlを参考にして、色々試してみることにしました。

ダウンロードは以下のサイトからできます。
http://jakarta.apache.org/site/downloads/downloads_commons-dbcp.cgi
http://archive.apache.org/dist/xml/xerces-j/

これらのパッケージ中に含まれるjarファイル
commons-dbcp-1.2.1.jar
resolver.jar
xercesImpl.jar
xercesSamples.jar
xml-apis.jar
xmlParserAPIs.jar

をCLASSPATHに通し、

joclファイルをCLASSPATHの通ったところにおいておけばOK。これでserver.xmlなどの書きかえは不要になります。
joclファイルはPoolableConnectionFactoryについて作成します。
同梱されているjavadocを見るとPoolableConnectionFactoryのコンストラクタは、２つ用意されています。
（４つはdeprecateされたクラスAbandonedConfigを使用しているため、deprecateされています）。
主な引数は、
1.org.apache.commons.dbcp.ConnectionFactory connFactory(これはInterface)
2.org.apache.commons.pool.ObjectPool pool(これもInterface)
3.org.apache.commons.pool.KeyedObjectPoolFactory(これもInterface) stmtPoolFactory
4.String validationQuery(検証用SQL)
5.boolean defaultReadOnly(読取専用)
6.boolean defaultAutoCommit(オートコミットデフォルト設定)
7.int defaultTransactionIsolation(デフォルトのTransaction分離レベル)

ここでは、
PoolableConnectionFactory(org.apache.commons.dbcp.ConnectionFactory connFactory, ObjectPool pool, KeyedObjectPoolFactory stmtPoolFactory, String validationQuery, Boolean defaultReadOnly, boolean defaultAutoCommit, int defaultTransactionIsolation)
を使用することにします。Transaction分離レベルについてはローラー作戦で一通り試してみました。
（ConnectionクラスのsetTransactionIsolationを使用しプロファイラを観察）。

setTransactionIsolationに与えた引数	プロファイラの結果
TRANSACTION_READ_UNCOMMITTED	SET TRANSACTION ISOLATION LEVEL READ UNCOMMITTED
TRANSACTION_READ_COMMITTED	SET TRANSACTION ISOLATION LEVEL READ COMMITTED
TRANSACTION_REPEATABLE_READ	SET TRANSACTION ISOLATION LEVEL REPEATABLE READ
TRANSACTION_SERIALIZABLE	SET TRANSACTION ISOLATION LEVEL SERIALIZABLE
TRANSACTION_NONE	SET TRANSACTION ISOLATION LEVEL(['LEVEL' の近くに無効な構文があります]の例外発生。)

そういうわけで、安心してdefaultTransactionIsolationには、上記のNONE以外のどれかが使えます。

早速joclファイル(PoolableConnectionFactory)を作成します。
<object class="org.apache.commons.dbcp.PoolableConnectionFactory"
xmlns="http://apache.org/xml/xmlns/jakarta/commons/jocl">

</object>
このタグの中に、コンストラクタの引数を埋め込んでいきます。

まず、1.のorg.apache.commons.dbcp.ConnectionFactory connFactoryから。
これはInterfaceなので、それを実装したDriverManagerConnectionFactoryを使用します。
コンストラクタは
DriverManagerConnectionFactory(String connectUri, String uname, String passwd)
を使用します。よって、この引数に相当するタグは以下のようになります。
<object class="org.apache.commons.dbcp.DriverManagerConnectionFactory">
   
   <string value="jdbc:microsoft:sqlserver://サーバー名:1433;databaseName=Northwind;selectMethod=cursor"/>
   
   <string value="sa"/>
   
   <string value="*******"/>
</object>

2.のorg.apache.commons.pool.ObjectPoolは、Interfaceneなのでそれを実装した
org.apache.commons.pool.impl.GenericObjectPoolを使用します。コンストラクタが11個もあります。
ここでは、
GenericObjectPool(PoolableObjectFactory factory, int maxActive, byte whenExhaustedAction, long maxWait, int maxIdle, int minIdle, boolean testOnBorrow, boolean testOnReturn, long timeBetweenEvictionRunsMillis, int numTestsPerEvictionRun, long minEvictableIdleTimeMillis, boolean testWhileIdle)
を使用することにします。
このコンストラクタ最初の引数、PoolableObjectFactoryもInterfaceですが、
<object class="org.apache.commons.pool.PoolableObjectFactory" null="true"/>
とできます。実際のConnection(poolされるobject)はPoolableConnectionFactoryが生成するそうなので、これでOK。
これは、
GenericObjectPool connectionPool = new GenericObjectPool(null, ......);
に相当します。
後の引数はプリミティブ型です。コンストラクタの引数並び順に並べると以下のようになります。

<object class="org.apache.commons.pool.impl.GenericObjectPool">
   
   <object class="org.apache.commons.pool.PoolableObjectFactory" null="true"/>
   
   <int value="50"/>
   
   <byte value="1"/>
   
   <long value="15000"/>
   
   <int value="50"/>
   
   <int value="10"/>
   
   <boolean value="true"/>
   
   <boolean value="false"/>
   
   <long value="10000"/>
   
   <int value="20"/>
   
   <long value="380000"/>
   
   <boolean value="false"/>
</object>

3.のKeyedObjectPoolFactoryもInterfaceなので、これを実装したStackKeyedObjectPoolFactoryを使用します。
<object class="org.apache.commons.pool.StackKeyedObjectPoolFactory"/>

4.の検証用SQLですがなるべく軽いものがいいです。oracleの場合、
SELECT COUNT(*) FROM DUALが使われているようですが、
SQL Serverの場合は
SELECT null
で良いと思います。

<string value="SELECT null"/>

5.の読取専用はもちろんfalseで

<boolean value="false"/>

6.のAuto Commitは、trueで

<boolean value="true"/>

7.最後のTransaction分離レベルですが、
java.sql.Connection
public static final int TRANSACTION_NONE 0
public static final int TRANSACTION_READ_COMMITTED 2
public static final int TRANSACTION_READ_UNCOMMITTED 1
public static final int TRANSACTION_REPEATABLE_READ 4
public static final int TRANSACTION_SERIALIZABLE 8
となっていますので、TRANSACTION_READ_COMMITTEDを明示的に指定するには

<int value="2"/>
とします(デフォルトは、TRANSACTION_READ_COMMITTEDなので本来は不要)。

以下、joclファイルの最終形です。これにsqlserver.jocl（拡張子以外任意）という名前をつけて、CLASSPATHの通ったところに配置します。

<object class="org.apache.commons.dbcp.DriverManagerConnectionFactory">
      
      <string value="jdbc:microsoft:sqlserver://サーバー名:1433;databaseName=Northwind;selectMethod=cursor"/>
      
      <string value="sa"/>
      
      <string value="**********"/>
   </object>

<object class="org.apache.commons.pool.impl.GenericObjectPool">
      
      <object class="org.apache.commons.pool.PoolableObjectFactory" null="true"/>
      
      <int value="50"/>
      
      <byte value="1"/>
      
      <long value="15000"/>
      
      <int value="50"/>
      
      <int value="15"/>
      
      <boolean value="true"/>
      
      <boolean value="false"/>
      
      <long value="10000"/>
      
      <int value="20"/>
      
      <long value="380000"/>
      
      <boolean value="false"/>
   </object>

   
   <object class="org.apache.commons.pool.StackKeyedObjectPoolFactory"/>

<string value="SELECT null"/>

<boolean value="false"/>

<boolean value="true"/>

<int value="2"/>
</object>

これを使用して色々実験してみます。
以下のように実験に使うServletを用意しました。

package org.passj.blogs.taniguchi.test_servlet;

import java.io.IOException;
import java.io.PrintWriter;
import java.sql.Connection;
import java.sql.DriverManager;

import javax.servlet.ServletException;
import javax.servlet.http.HttpServlet;
import javax.servlet.http.HttpServletRequest;
import javax.servlet.http.HttpServletResponse;

/**
* @author たにぐち
*
*/
public class TestServlet extends HttpServlet {
    public void doGet(HttpServletRequest req, HttpServletResponse res)
            throws ServletException, IOException {
        res.setContentType("text/html;charset=Shift_JIS");
        PrintWriter out = res.getWriter();
        Connection con = null;
        out.println("<html>\n");
        out.println("<head><title>コネクションプーリングのテスト</title></head>\n");
        out.println("<body>");
        out.println("<P>コネクションプーリングをテストします。");
        try {
            // デフォルトのSAXドライバの指定
            if (System.getProperty("org.xml.sax.driver") == null) {
                System.setProperty("org.xml.sax.driver",
                        "org.apache.xerces.parsers.SAXParser");
            }
            // ドライバをロードします
            Class.forName("org.apache.commons.dbcp.PoolingDriver");
            Class.forName("com.microsoft.jdbc.sqlserver.SQLServerDriver");
            // Connectionを取得します
            // "/sqlserver"のsqlserverは、sqlservelr.joclのファイル名から拡張子を除いたもの
            // スラッシュを忘れずに。
            con = DriverManager.getConnection("jdbc:apache:commons:dbcp:/sqlserver");
            out.println("<P>成功！");
            // 必要に応じてsleepする
            Thread.sleep(待ち時間ミリ秒);
        } catch (Exception e) {
            out.println("<P>ただいま接続が混雑しております");
            e.printStackTrace();
        } finally {
            closeConnection(con);
        }
        out.println("</body>");
    }
    private void closeConnection(Connection con) {
        try {
            if (con != null) {
                con.close();
            }
        } catch (Exception e) {
            e.printStackTrace();
        }
    }
}

主役的な役割を果たすのは「排除スレッド」です。この排除スレッドは「排除スレッドの実行間隔」おきに実行され、アイドル状態の接続を「最小アイドル数」以上「最大アイドル数」以下に保ちます。
アイドル状態接続が追加されるのはアイドル状態接続数が「最小アイドル数」を下回った時、削除されるのはアイドル状態接続数が「最大アイドル数」を上回った時です。
またアイドル接続が「排除対象になるまでの最短時間」を上回っていた場合もアイドル接続を削除の対象にします。
ただし、削除されることにより「最小アイドル数」を下回ってしまった場合、直ちに不足した分を追加します。
また、検証用クエリを用いたコネクションのテスト（取得時、返却時、アイドル状態）も行います（指定されていた時のみ）。
設定を間違えるとかえってシステムに負担をかけてしまうので注意が必要です。

Solaris10からSQL Server 2000 (JDBC) その３

たにぐち — Sun, 12 Jun 2005 05:32:00 GMT

http://blogs.sqlpassj.org/masatotaniguchi/archive/2005/05/23/9102.aspx
の続きです。

今度はストアドプロシージャを実行してみました。
runSqlメソッドを以下のように変更します（DBはNorthwindを使用しました。ストアド３は自作で、数値を戻すだけの簡単なものです）。

   public void runSql() {
      Connection con = getConnection();
      if (con != null) {
         try {

            // ストアド１：結果セット１個
            CallableStatement cstmt = con.prepareCall("{Call [dbo].[CustOrderHist] (?)}");
            cstmt.setString(1, "OTTIK");
            ResultSet rs = cstmt.executeQuery();
            System.out.println("CustOrderHist");
            while (rs.next()) {
               System.out.println(rs.getString("ProductName") + ":" + rs.getInt("Total"));
            }
            rs.close();
            cstmt.close();

            // ストアド２：結果セット複数
            cstmt = con.prepareCall("{Call [dbo].[sp_helpdb] (?)}");
            cstmt.setString(1, "Northwind");
            rs = cstmt.executeQuery();
            // 一つ目結果セット
            System.out.println("sp_helpdb 1");
            while (rs.next()) {
               System.out.println(rs.getString("name") + ":" + rs.getString("db_size"));
            }
            rs.close();
            // CallableStatementのgetMoreResultsメソッド
            // さらに結果セットがある場合はそれを取得する
            // あればtrueを返す
            cstmt.getMoreResults();
            rs = cstmt.getResultSet();
            // 二つ目結果セット
            System.out.println("sp_helpdb 2");
            while (rs.next()) {
               System.out.println(rs.getString("name") + ":" + rs.getString("filename"));
            }
            rs.close();
            cstmt.close();

            // ストアド３：戻り値付きストアド
            cstmt = con.prepareCall("{? = call [dbo].[test]}");
            cstmt.registerOutParameter(1, Types.INTEGER);
            cstmt.execute();
            System.out.println("戻り値付き");
            System.out.println(cstmt.getInt(1));
            cstmt.close();

         } catch (Exception ex) {
            ex.printStackTrace();
         } finally {
            closeConnection(con);
         }
      }
   }

結果セットを返すストアドプロシージャも違和感なく処理できます。しかも複数結果セットもOKです。

ちなみにプロファイラの結果は以下のようになりました。

exec sp_executesql N'EXEC [dbo].[CustOrderHist] @P1 ', N'@P1 nvarchar(4000) ', N'OTTIK'

exec sp_executesql N'EXEC [dbo].[sp_helpdb] @P1 ', N'@P1 nvarchar(4000) ', N'Northwind'

exec sp_executesql N'EXEC @P1 = [dbo].[test] ', N'@P1 int OUTPUT ', @P1 output
select @P1

今度は、sp_executesqlを使用しているようです。

これと同じことをOracleでやろうとすると次のようになります。
テーブルはおなじみのscottのempを使用します。

oracle側ストアドプロシージャ

   CREATE OR REPLACE PACKAGE pkgEMP IS
      type emp_cursor is ref cursor return EMP%rowtype;
      procedure SelectEmp (key in number, rc1 in out emp_cursor, rc2 in out emp_cursor );
   END;
   /
   CREATE OR REPLACE PACKAGE BODY pkgEMP IS
      PROCEDURE SelectEmp (key in number, rc1 in out emp_cursor, rc2 in out emp_cursor ) IS
      BEGIN
         open rc1 for select * from EMP where EMPNO = key;
         open rc2 for select * from EMP;
      END SelectEmp;
   END pkgEMP;
   /

Java側

   public void runSQL() {
      Connection con = getConnection();
      if (con != null) {
         try {
            CallableStatement cstmt = con.prepareCall("{Call pkgEMP.SelectEmp (?, ?, ?)}");
            cstmt.setInt(1, 7839);
            cstmt.registerOutParameter(2, OracleTypes.CURSOR);
            cstmt.registerOutParameter(3, OracleTypes.CURSOR);
            cstmt.execute();
            ResultSet rs1 = ((OracleCallableStatement)cstmt).getCursor(2);
            ResultSet rs2 = ((OracleCallableStatement)cstmt).getCursor(3);
            while (rs1.next()) {
               System.out.println(rs1.getString("ENAME") + ":" + rs1.getString("JOB"));
            }
            while (rs2.next()) {
               System.out.println(rs2.getString("ENAME") + ":" + rs2.getString("JOB"));
            }
            rs1.close();
            rs2.close();
            cstmt.close();
         } catch (Exception ex) {
            ex.printStackTrace();
         } finally {
            closeConnection(con);
         }
      }
   }

SQL Serverの場合、ストアドが出力した結果セットはexecuteQueryの戻り値として取得するのに対して、Oraceleのほうはカーソルを出力パラメータとして受け取るんですね。
Javaのお相手としてOracleが使われることが多いようですが、SQL Serverも結構いけそうです。いかがでしょうか？

#Solaris版Eclipse、苦労の末ようやく慣れてきました(^^;

Visual Basic 6.0で、なるべくコードの変更を少なくして複数のデータベースに確実に対応できるようにする

たにぐち — Fri, 10 Jun 2005 01:16:00 GMT

谷口です

Visual Basic 6.0で、なるべくコードの変更を少なくして複数のデータベースに確実に対応できるようにする方法についてです。
方法は色々考えられると思いますが、ここではVBのインターフェース(Interface)継承を用いてみようと思います。オブジェクト指向を完全にサポートしていないVisual Basic 6.0ですが、やれるところまでやってみようというお話です。

使用するDBはSQL Server 2000とOracleです。
テーブルはOracleの、scottにあるempテーブルを用います。
これを、SQL server 2000にインポートしました。
※以下のソースコードはエラー処理などが省略してあり、完全ではありません。
このテーブルのレコードを保存するために、VO(Value Object)を用意します。

' ソースコード(clsEmpVo)：クラスモジュール

' Private 変数
' 従業員番号
Private m_lngEmpNo As Long
' 従業員名
Private m_strEname As String

' 以下略

' プロパティ

Public Property Get EMPNO() As Long
EMPNO = m_lngEmpNo
End Property

Public Property Let EMPNO(lngEmpNo As Long)
m_lngEmpNo = lngEmpNo
End Property

Public Property Get Ename() As String
Ename = m_strEname
End Property

Public Property Let Ename(strEname As String)
m_strEname = strEname
End Property

' 以下略（フィールド分同じものを作ります）

次に、データアクセス用インターフェースクラスを定義します

' ソースコード(clsEmpDao) ：クラスモジュール

Public Function SelectEmp(lngEmpNo As Long) As Collection

End Function

Public Function InsertEmp(EmpVo As clsEmpVo) As Boolean

End Function

Public Function UpdateEmp(EmpVo As clsEmpVo) As Boolean

End Function

このクラスのメソッドの中身は実装しません。

次にこれをImplementsしたSQL Server用クラスを作成します。
（ADO接続用オブジェクトは定義済みとします）

' ソースコード(clsEmpSQLServerDao)：クラスモジュール

Implements clsEmpDao

Public Function clsEmpDao_SelectEmp(lngEmpNo As Long) As Collection

    Dim cmd As New ADODB.Command
    Dim result As New Collection
    Dim rs As ADODB.Recordset

    ' Commandの設定
    With cmd
        .ActiveConnection = adoSQLServerCon
        .CommandText = "SELECT * FROM EMP WHERE EMPNO = ?"
        .CreateParameter , adInteger, adParamInput
        .Parameters(0).Value = lngEmpNo
    End With

    ' SQLを実行して結果セットを取得します
    Set rs = cmd.Execute

    ' Recordsetから、VOへ値を詰めます
    Do Until rs.EOF
        Dim EmpVo As clsEmpVo
        Set EmpVo = New clsEmpVo
        ' 修正2005/07/08
        ' ここで Dim EmpVo = New clsEmpVoとやると
        ' EmpVoが使いまわされ、同じ値になってしまう
        EmpVo.EMPNO = lngEmpNo
        EmpVo.Ename = nvl(rs.Fields("ENAME"), "")
        EmpVo.Job = nvl(rs.Fields("JOB"), "")
        EmpVo.Mgr = nvl(rs.Fields("MGR"), 0)
        EmpVo.HireDate = nvl(rs.Fields("HireDate"), 0)
        EmpVo.Sal = nvl(rs.Fields("SAL"), 0)
        EmpVo.Comm = nvl(rs.Fields("COMM"), 0)
        EmpVo.DeptNo = nvl(rs.Fields("DEPTNO"), 0)
        Call result.Add(EmpVo)
        rs.MoveNext
    Loop

    ' 後始末
    rs.Close
    Set rs = Nothing

    ' 戻り値(VOのコレクション)の設定
    Set clsEmpDao_SelectEmp = result

End Function

Public Function clsEmpDao_InsertEmp(EmpVo As clsEmpVo) As Boolean
' 省略
End Function

Public Function clsEmpDao_UpdateEmp(EmpVo As clsEmpVo) As Boolean
' 省略
End Function

ポイントは先頭のImplements clsEmpDaoと、メソッド名の前にアンダーバーを使いインターフェースクラス名をつけることです。インターフェースクラスで定義されているメソッドは全て実装する必要があります。

同じくOracle用を作成します。ここではoo4oを使用しています。

' ソースコード(clsEmpOracleDao)：クラスモジュール

Implements clsEmpDao

Public Function clsEmpDao_SelectEmp(lngEmpNo As Long) As Collection

    Dim oraDynaset As Object
    Dim result As New Collection

    ' パラメータのキー(EMPNO)
    Const EMPNO As String = "EMPNO"

    ' パラメータの定義
    oraDatabase.Parameters.Add EMPNO, lngEmpNo, ORAPARM_INPUT
    oraDatabase.Parameters(EMPNO).serverType = ORATYPE_NUMBER

    ' Dynaset
    Set oraDynaset = oraDatabase.CreateDynaset("SELECT * FROM EMP WHERE EMPNO = :EMPNO", 0&)

    ' DynasetkaからVOへ値を詰めます
    Do Until oraDynaset.EOF
        Dim EmpVo As clsEmpVo
        Set EmpVo = New clsEmpVo
        ' 修正2005/07/08
        ' ここで Dim EmpVo = New clsEmpVoとやると
        ' EmpVoが使いまわされ、同じ値になってしまう
        EmpVo.EMPNO = lngEmpNo
        EmpVo.Ename = nvl(oraDynaset.Fields("ENAME"), "")
        EmpVo.Job = nvl(oraDynaset.Fields("JOB"), "")
        EmpVo.Mgr = nvl(oraDynaset.Fields("MGR"), 0)
        EmpVo.HireDate = nvl(oraDynaset.Fields("HireDate"), 0)
        EmpVo.Sal = nvl(oraDynaset.Fields("SAL"), 0)
        EmpVo.Comm = nvl(oraDynaset.Fields("COMM"), 0)
        EmpVo.DeptNo = nvl(oraDynaset.Fields("DEPTNO"), 0)
        Call result.Add(EmpVo)
        oraDynaset.MoveNextn 1
    Loop

    ' 後始末
    oraDatabase.Parameters.Remove EMPNO
    oraDynaset.Close
    Set oraDynaset = Nothing

    ' 戻り値(VOのコレクション)の設定
    Set clsEmpDao_SelectEmp = result

End Function

Public Function clsEmpDao_InsertEmp(EmpVo As clsEmpVo) As Boolean
' 省略
End Function

Public Function clsEmpDao_UpdateEmp(EmpVo As clsEmpVo) As Boolean
' 省略
End Function

データベース変更時のコード変更を楽にするために次のようなクラスを作ります。
プログラム中でEmpDaoクラスを作成する時は必ずこのクラスを使用するようにします。そうすることにより使用するデータベースをここで一括管理できます（他にもDaoクラスを作った時は全てここに生成関数を作ります）。ＤＢ接続のためのオブジェクト（clsEmpSQLServerDaoのadoSQLServerConやclsEmpOracleDaoのoraDatabase）についてはここでは詳しく扱いませんが、clsEmpDaoにプロパティを追加し(Property Set)、わたしてやるのがよいかもしれません。この方法は、この投稿のASP版

http://blogs.sqlpassj.org/masatotaniguchi/archive/2005/07/09/12119.aspx

で扱ってみました。

' ソースコード(clsScottDaoFactory) ：クラスモジュール

Public Function EmpDao() As clsEmpDao
    Dim Emp As clsEmpDao
    ' 変更の必要な箇所
    Set Emp = New clsEmpSQLServerDao
    ' Set Emp = New clsEmpOracleDao
    Set EmpDao = Emp
End Function

' 他のDaoクラスの例
Public Function DeptDao() As clsDeptDao
    ' 略
End Function

次はこれらのクラスの使用例です。

' ソースコード（Form1）：フォームモジュール

Private Sub Command1_Click()

    Dim result As Collection
    Dim ScottDaoFactory As New clsScottDAOFactory
    Dim EmpDao As clsEmpDao
    Dim EmpVo As clsEmpVo

    Set EmpDao = ScottDaoFactory.EmpDao
    Set result = EmpDao.SelectEmp(7839)

    Set EmpVo = result.Item(1)

    Text1.Text = EmpVo.Ename

End Sub

従業員番号が'7839'のものを選択する簡単なコードですが、DBを変更する必要が出た時に加える修正は実装クラスさえ作成してあれば１行ですみます。InterfaceクラスclsEmpDaoは入れ物の役目をしていて、入れ物には「何をするか」の定義だけが書かれています。必要に応じて中身を入れ替えるという考え方です。
DBによる違いは全て実装クラスで吸収できます。
MDI子ウィンドウの管理など他にも応用例があります。

Solaris10からSQL Server 2000 (JDBC) その２

たにぐち — Wed, 01 Jun 2005 02:46:00 GMT

Solaris10からSQL Server 2000 (JDBC)
の続きです。

runSQLメソッドを以下のように変更します。

   public void runSql() {
      Connection con = getConnection();
      if (con != null) {
         try {
            PreparedStatement ps =
               con.prepareStatement("SELECT * FROM 住所録 WHERE id = ?");
            ps.setInt(1, 1);
            ResultSet rs = ps.executeQuery();
            while (rs.next()) {
               String contactName = rs.getString("名前");
               System.out.println(contactName);
            }
            rs.close();
            ps.close();
         } catch (Exception ex) {
            ex.printStackTrace();
         } finally {
            closeConnection(con);
         }
      }
   }

ちなみに、見に行くのは「住所録」という日本語名のテーブルの、「名前」
というフィールド。id = 1には「たにぐち」と入っています。

結果は

接続成功！
たにぐち

と無事に出力されました。どうやら日本語は大丈夫のようですね。

以下プロファイラの出力です。PreparedStatementのパラメータが
どのように処理されているか!？

select @@MAX_PRECISION

declare @P1 int
set @P1=180150000
declare @P2 int
set @P2=4
declare @P3 int
set @P3=1
declare @P4 int
set @P4=-1
exec sp_cursoropen @P1 output, N'SELECT * FROM 住所録 WHERE id = @P1', @P2 output, @P3 output, @P4 output, N'@P1 int ', 1
select @P1, @P2, @P3, @P4

exec sp_cursorfetch 180150000, 2, 1, 256

exec sp_cursorclose 180150000

API システムストアドプロシージャを使用しています。
このプロシージャは直接の呼出はサポートしていないそうです（なのでBooks Onlineにも
使用方法は書かれていません）。
ADO、OLE DB、ODBC、および DB-Library などから呼ばれると書いてありますが、
JDBC Driverもこの中に入るようです。
詳しくはBooks Online参照。

ここで、Visual Basic 6.0の登場。ADOをつかいDSNで接続。

Private Sub Command1_Click()

    Dim adoCon As New ADODB.Connection
    Dim cmd As New ADODB.Command
    Dim rs As New ADODB.Recordset

    adoCon.ConnectionString = _
        "DSN=********;DATABASE=xxxxxx;UID=sa;PWD=********"
    adoCon.Open

    With cmd
        .ActiveConnection = adoCon
        .CommandText = "SELECT * FROM 住所録 WHERE id = ?"
        .CreateParameter , adInteger, adParamInput
        .Parameters(0).Value = 1
    End With

    Set rs = cmd.Execute
    Do Until rs.EOF
        Debug.Print rs.Fields("名前").Value
        rs.MoveNext
    Loop
    rs.Close
    adoCon.Close
End Sub

プロファイラの結果は

declare @P1 int
set @P1=1
exec sp_prepare @P1 output, N'@P1 int', N'SELECT * FROM 住所録 WHERE id = @P1', 1
select @P1

同様にAPI システムストアドプロシージャを使っていますが、別なストアド(sp_prepare)を使っています。

ADO.NETの場合は、確かsp_executesql。これならBooks Onlineに使い方が載っています。

ううん、同じことをしているはずなのに色々ですね。

それにしてもSolaris版(motif)Eclipseちょっと重いです。仕事で使うにはちょっとツラそう。